Callui

Syntaxe

Callui retour = "" with action, liste_param

Paramètres

Elément	Description	Restrictions
retour	retour d'information sous forme d'une chaîne de caractères
action	code action : chaîne de caractères sous la forme : "UIAction="+chr$(1)+"valeur_action"
liste_param	Liste de *id_param* séparés par le caractère ','.	Les expressions doivent être alphanumériques et sont limitées à 255.
id_param	paramètre : chaîne de caractères sous la forme : "cd_param="+chr$(1)+"valeur_param"	Les expressions doivent être alphanumériques et sont limitées à 255.

Exemples

# Exemple 1 : copier un fichier du serveur sur le poste client
Callui RETOUR="" With "UIAction="+chr$(1) + "GetFileAlways",
& "UIRemoteFile="+ chr$(1) + "PIC/AUS_PC.jpg",
& "UILocalFile="+ chr$(1) + "Pepere.jpg",
& "UILocalDir="+chr$(1) + "RtsTemp"
Infbox "GetFileAlways"+RETOUR
# Exemple 2 : ouvrir ce fichier ( sur le poste client)
Callui RETOUR="" With "UIAction="+chr$(1)+"OpenFile",
& "UILocalDir="+chr$(1) + "RtsTemp",
& "UILocalFile="+ chr$(1) +"Pepere.jpg"
Infbox "OpenFile"+RETOUR
# Exemple 3 : ouvrir une session du navigateur internet
Callui RETOUR="" With "UIAction="+chr$(1)+"OpenFile",
& "UILocalDir="+chr$(1) + "HTTP",
& "UILocalFile="+ chr$(1) +"www.meteo.fr"
########################################################################
# Exemple 4
# Ouverture d'un lien http sur un répertoire publié du serveur
#########################################################################
Subprog OPEN_HTTP(URL)
Value Char URL
Local Char RETOUR (250)
Callui RETOUR="" With "UIAction="+chr$(1)+"OpenFile",
& "UILocalDir="+ chr$(1) +"HTTP",
& "UILocalFile="+ chr$(1) +URL,
& "UIAdxPubSubFile="+ chr$(1) + "1"
End

Description

Callui permet de piloter le client. Le client reçoit (via le moteur) l'ordre d'exécuter un Callui. Il interprète les paramètres associés, et il prend en charge le transfert ou l'ouverture du fichier.

Callui permet de lancer l'une des actions suivantes :

transférer un fichier du serveur vers le poste client
transférer un fichier du poste client vers le serveur
ouvrir un fichier sur le poste client
ouvrir une session du navigateur internet installé sur le poste client et sollicite l'URL passée dans le paramètre"UlLocalFile".
ouvrir une session du navigateur internet avec une 'URL correspondant à un sous fichiers du dossier X3_PUB. Le paramètre"UlLocalFile" contient l'url relatif sous la forme "AdonixApplicationServerHostName:port/AliasOfProxyPath/[solution] et le paramètre UIAdxPubSubFile doit être positionné à 1.

Une seule action peut être précisée à la fois.

En retour, nous avons un code nous précisant que l'action s'est bien déroulée ou pas.

action :

Ce paramètre permet d'identifier l'action à lancer sur le client.

Les actions disponibles sont les suivantes :

Action	Description
OpenFile	Ouverture de fichier sur le poste client
GetFile	Transfert d'un fichier du serveur vers le poste client seulement si le fichier du serveur est plus récent
GetFileAlways	Transfert d'un fichier du serveur vers le poste client
PutFile	Transfert d'un fichier du poste client vers le serveur seulement si le fichier du serveur est plus récent
PutFileAlways	Transfert d'un fichier du poste client vers le serveur

id_param

Il permet de préciser les paramètres d'une action.

la liste des paramètres est la suivante :

Paramètres	Description
UILocalFile	Nom du fichier sur le poste client ou l'URL lorsque le paramètre "UlLocalDir" = HTTP ( l'URL ne devant pas comporter le préfixe "http://") Attention ! l'URL ne peut pas dépasser 240 caractères.
UILocalDir	Répertoire du fichier sur le poste client. 3 répertoires sont disponibles : Temp : installdir\X3\Temp Report : installdir\X3\Report\dossier_serveur_service RtsTemp : nstalldir\X3\RTS\Temp si le répertoire n'est pas précisé, TEMP est pris par défaut
UIRemoteFile	Nom du fichier sur le poste serveur, précédé du chemin. on précise le chemin à partir du répertoire d'installation du dossier exemple : "REPORT/ARCCLIENT.rpt"
UIAdxPubSubFile	Flag positionné à 1, permet d'identifier les urls correspondants à des sous-fichiers du dossier X3_PUB.

Liste des paramètres possibles par action :

Action	Paramètres
OpenFile	UILocalDir
	UILocalFile

GetFile GetFileAlways PutFile PutFileAlways	UILocalDir
	UILocalFile
	UIRemoteFile

retour :

Ce paramètre permet d'identifier la variable qui contiendra les informations de retour de l'instruction.

En retour, l'instruction nous envoie le nom de l'action, suivi du code statut.

Le code statut prend l'une ou l'autre des valeurs suivantes :

1 : l'action s'est déroulée correctement
0 : une erreur s'est produite au cours de l'action.

Particularités Web

En web, comme pour les ordres Openi, Openo et Openio , il n'est pas possible par un Callui d'ouvrir ou d'écrire un fichier situé sur le poste client. Par contre, le Callui UIlocaldir=HTTP fonctionne et permet d'ouvrir une instance de browser.

Evolutions

C'est une nouvelle instruction.

Erreurs associées

Erreur	Description

Mots-clés associés

GETUI - ASKUI